Hoe de Excel VERT.ZOEKEN-functie - te gebruiken

Samenvatting

VERT.ZOEKEN is een Excel-functie om gegevens op te zoeken in een verticaal georganiseerde tabel. VERT.ZOEKEN ondersteunt geschatte en exacte overeenkomsten, en jokertekens (*?) Voor gedeeltelijke overeenkomsten. Opzoekwaarden moeten verschijnen in de eerste kolom van de tabel die is doorgegeven aan VERT.ZOEKEN.

Doel

Zoek een waarde op in een tabel door deze in de eerste kolom te matchen

Winstwaarde

De overeenkomende waarde uit een tabel.

Syntaxis

= VERT.ZOEKEN (waarde, tabel, col_index, (range_lookup))

Argumenten

waarde : de waarde waarnaar moet worden gezocht in de eerste kolom van een tabel.
table - De tabel waaruit een waarde moet worden opgehaald.
col_index - De kolom in de tabel waaruit een waarde moet worden opgehaald.
range_lookup - (optioneel) TRUE = geschatte overeenkomst (standaard). FALSE = exacte overeenkomst.

Versie

Excel 2003

Gebruiksopmerkingen

VERT.ZOEKEN is een Excel-functie om gegevens uit een verticaal georganiseerde tabel op te halen. Opzoekwaarden moeten verschijnen in de eerste kolom van de tabel die is doorgegeven aan VERT.ZOEKEN. VERT.ZOEKEN ondersteunt geschatte en exacte overeenkomsten, en jokertekens (*?) Voor gedeeltelijke overeenkomsten.

V is voor verticaal

Het doel van VERT.ZOEKEN is om informatie op te halen uit een tabel die als volgt is ingedeeld:

Door het bestelnummer in kolom B als opzoekwaarde te gebruiken, kan VERT.ZOEKEN de klant-ID, het bedrag, de naam en de staat voor elke bestelling ophalen. Om bijvoorbeeld de klantnaam voor bestelling 1004 te krijgen, is de formule:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Voor horizontale gegevens kunt u HLOOKUP, INDEX en MATCH of XLOOKUP gebruiken.

VERT.ZOEKEN is gebaseerd op kolomnummers

Wanneer u VERT.ZOEKEN gebruikt, stel u dan voor dat elke kolom in de tabel genummerd is, beginnend van links. Om een waarde uit een bepaalde kolom te halen, geeft u het juiste nummer op als de "kolomindex". De kolomindex om de onderstaande voornaam op te halen is bijvoorbeeld 2:

De achternaam en het e-mailadres kunnen worden opgehaald met de kolommen 3 en 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

VERT.ZOEKEN ziet er alleen goed uit

VERT.ZOEKEN kan alleen naar rechts kijken. De gegevens die u wilt ophalen (resultaatwaarden) kunnen in elke kolom rechts van de opzoekwaarden verschijnen:

Zie INDEX en MATCH of XLOOKUP als u waarden aan de linkerkant moet opzoeken.

Exacte en geschatte matching

VERT.ZOEKEN heeft twee manieren om te matchen, exact en bij benadering. De naam van het argument dat de overeenkomst beheert, is " range_lookup ". Dit is een verwarrende naam, omdat het iets te maken lijkt te hebben met celbereiken zoals A1: A10. In feite verwijst het woord "bereik" in dit geval naar "bereik van waarden" - wanneer bereik_opzoeken TRUE is, zal VERT.ZOEKEN overeenkomen met een bereik van waarden in plaats van een exacte waarde. Een goed voorbeeld hiervan is het gebruik van VERT.ZOEKEN om cijfers te berekenen.

Het is belangrijk om te begrijpen dat range_lookup standaard TRUE is, wat betekent dat VERT.ZOEKEN standaard geschatte overeenkomsten gebruikt, wat gevaarlijk kan zijn. Stel range_lookup in op FALSE om exacte overeenkomst af te dwingen:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Opmerking: u kunt ook nul (0) opgeven in plaats van FALSE voor een exacte overeenkomst.

Exacte overeenkomst

In de meeste gevallen wilt u VERT.ZOEKEN waarschijnlijk gebruiken in de modus voor exact zoeken. Dit is logisch als u een unieke sleutel heeft om als opzoekwaarde te gebruiken, bijvoorbeeld de filmtitel in deze gegevens:

De formule in H6 om Jaar te vinden , gebaseerd op een exacte overeenkomst met de filmtitel, is:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Geschatte overeenkomst

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.