Generieke formule
=INT(end-start)&" days "&TEXT(end-start,"h"" hrs ""m"" mins """)
Samenvatting
Om de dagen, uren en minuten tussen twee datums te berekenen en weer te geven, kunt u de TEXT-functie gebruiken met een beetje hulp van de INT-functie. In het getoonde voorbeeld is de formule in D5:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins """)
Uitleg
Het meeste werk in deze formule wordt gedaan door de TEXT-functie, die een aangepaste getalnotatie voor uren en minuten toepast op een waarde die is gecreëerd door de begindatum af te trekken van de einddatum.
TEXT(C5-B5,"h"" hrs ""m"" mins """)
Dit is een voorbeeld van het insluiten van tekst in een aangepast getalnotatie, en deze tekst moet tussen een extra paar dubbele aanhalingstekens staan. Zonder de extra dubbele aanhalingstekens ziet het aangepaste tekstformaat er als volgt uit:
h "hrs" m "min"
De waarde voor dagen wordt berekend met de INT-functie, die eenvoudig het gehele gedeelte van de einddatum minus de startdatum retourneert:
INT(C5-B5) // get day value
Opmerking: hoewel u "d" in een aangepaste getalnotatie voor dagen kunt gebruiken, wordt de waarde gereset naar nul wanneer dagen groter zijn dan 31.
Voeg seconden toe
Als u seconden wilt opnemen, kunt u de aangepaste getalnotatie als volgt uitbreiden:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins ""s"" secs""")
Totaal aantal dagen, uren en minuten tussen datums
Om het totale aantal dagen, uren en minuten tussen een set start- en einddatums te krijgen, kunt u de formule met SOMPRODUCT als volgt aanpassen:
=INT(SUMPRODUCT(ends-starts))&" days "&TEXT(SUMPRODUCT(ends-starts),"h"" hrs ""m"" mins """)
waar "eindigt" staat voor het bereik van einddatums en "begint" voor het bereik van startdatums. In het getoonde voorbeeld bevat D11 deze formule:
=INT(SUMPRODUCT(C5:C9-B5:B9))&" days "&TEXT(SUMPRODUCT(C5:C9-B5:B9),"h"" hrs ""m"" mins """)
