Generieke formule
=MAXIFS(sales,dates,">="&G4,dates,"<="&EOMONTH(G4,0))
Samenvatting
Om de maximale waarde in een bepaalde maand te vinden, kunt u de MAXIFS-functie of een van de andere onderstaande alternatieven gebruiken. In het getoonde voorbeeld is de formule in G5:
=MAXIFS(sales,dates,">="&G4,dates,"<="&EOMONTH(G4,0))
Waarbij verkoop (D5: D15), datums (B5: B15) en waarden (C5: C15) benoemde bereiken zijn.
Uitleg
De MAXIFS-functie kan de maximale waarde in een bereik vinden op basis van een of meer criteria. In het getoonde voorbeeld gebruiken we MAXIFS om de maximale verkoopwaarde te vinden op basis van een bepaalde maand door datums tussen de eerste dag van de maand en de laatste dag van de maand "bracketing" te geven. Het eerste criterium controleert of datums groter zijn dan of gelijk zijn aan de eerste van de maand:
dates,">="&G4,dates // first of month
Opmerking: we gaan ervan uit dat de datum in G4 een "eerste maand" -datum is.
Het tweede criterium controleert of datums kleiner zijn dan of gelijk zijn aan de laatste van de maand, berekend met de functie EOMONTH:
dates,"<="&EOMONTH(G4,0) // last of month
Als beide criteria WAAR retourneren, valt de datum in de opgegeven maand en geeft MAXIFS de maximale waarde van datums die voldoen aan de criteria.
Alternatieve formules
Als uw versie van Excel de MAXIFS-functie niet bevat, zijn er andere opties. Een optie is een eenvoudige matrixformule op basis van de MAX- en IF-functies:
(=MAX(IF(TEXT(dates,"my")=TEXT(G4,"my"),sales)))
Opmerking: dit is een matrixformule en moet worden ingevoerd met met control + shift + enter.
Een andere optie is om de AGGREGATE-functie als volgt te gebruiken:
=AGGREGATE(14,6,sales/(TEXT(dates,"my")=TEXT(G4,"my")),1)
Beide bovenstaande opties gebruiken een eenvoudigere methode om datums te testen op basis van de TEXT-functie die een getalnotatie gebruikt om de maand en het jaar uit een datum te halen. De TEXT-functie kan niet op deze manier worden gebruikt binnen de MAXIFS-functie, omdat MAXIFS een bereik vereist. Deze alternatieve benaderingen worden hier in meer detail uitgelegd.
De maximale klant
Om de client op te halen die is gekoppeld aan de maximale waarde in een bepaalde maand, is de formule in G6:
(=INDEX(clients,MATCH(1,(sales=G5)*(TEXT(dates,"my")=TEXT(G4,"my")),0)))
Dit is een matrixformule en moet worden ingevoerd met met control + shift + enter.
Het idee hier is dat we de maximale waarde in een maand (G5) al kennen en die waarde kunnen gebruiken als een "sleutel" om de client op te zoeken. Merk op dat we de logica die wordt gebruikt om waarden in de opgegeven maand te isoleren, moeten herhalen om een valse match in een andere maand te voorkomen.
Net als de hierboven genoemde alternatieven, gebruiken deze formules ook een vereenvoudigde test voor datums op basis van de TEXT-functie. Lees hier meer over INDEX en MATCH met meerdere criteria.
Voor een alles-in-één formule vervangt u G5 door een van de formule-opties die hierboven zijn uitgelegd om de maximale waarde in een bepaalde maand te bepalen.
