Samenvatting
Om de totale inkomstenbelasting te berekenen op basis van meerdere belastingschijven, kunt u VERT.ZOEKEN gebruiken en een tarieftabel die is gestructureerd zoals weergegeven in het voorbeeld. De formule in G5 is:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
waarbij "inc" (G4) en "tarieven" (B5: D11) bereiken worden genoemd, en kolom D een hulpkolom is die de totale geaccumuleerde belasting voor elke schijf berekent.
Achtergrond en context
Het Amerikaanse belastingstelsel is "progressief", wat betekent dat mensen met een hoger belastbaar inkomen een hoger federaal belastingtarief betalen. Tarieven worden beoordeeld tussen haakjes gedefinieerd door een boven- en ondergrens. Het bedrag aan inkomen dat in een bepaalde schijf valt, wordt belast tegen het overeenkomstige tarief voor die schijf. Naarmate het belastbaar inkomen toeneemt, wordt het inkomen over meer belastingschijven belast. Veel belastingbetalers betalen daarom verschillende tarieven.
In het getoonde voorbeeld zijn de belastingschijven en tarieven voor enkelvoudige indieners in de Verenigde Staten voor het belastingjaar 2019. De onderstaande tabel toont de handmatige berekeningen voor een belastbaar inkomen van $ 50.000:
| Haakje | Berekening | Belasting |
|---|---|---|
| 10% | ($ 9.700 - $ 0) x 10% | $ 970,00 |
| 12% | ($ 39.475 - $ 9.700) x 12% | $ 3.573,00 |
| 22% | ($ 50.000 - $ 39.475) x 22% | $ 2.315,50 |
| 24% | NA | $ 0,00 |
| 32% | NA | $ 0,00 |
| 35% | NA | $ 0,00 |
| 37% | NA | $ 0,00 |
De totale belasting is dus $ 6.858,50. (weergegeven als 6.859 in het getoonde voorbeeld).
Setup-opmerkingen
1. Deze formule is afhankelijk van de functie VERT.ZOEKEN in "geschatte overeenkomstmodus". In geschatte overeenkomstmodus scant VERT.ZOEKEN de opzoekwaarden in een tabel (die in oplopende volgorde moeten worden gesorteerd) totdat een hogere waarde wordt gevonden. Dan zal het "een stap terug doen" en een waarde uit de vorige rij retourneren. In het geval van een exacte overeenkomst, retourneert VERT.ZOEKEN resultaten van de overeenkomende rij.
2. Om VERT.ZOEKEN de werkelijke cumulatieve belastingbedragen te laten ophalen, zijn deze aan de tabel toegevoegd als een hulpkolom in kolom D. De formule in D6, naar beneden gekopieerd, is:
=((B6-B5)*C5)+D5
Bij elke rij past deze formule het tarief uit de rij hierboven toe op het inkomen in die schijf.
3. Voor de leesbaarheid zijn de volgende benoemde bereiken gedefinieerd: "inc" (G4) en "rates" (B5: D11).
Uitleg
In G5 is de eerste VERT.ZOEKEN geconfigureerd om de cumulatieve belasting tegen het marginale tarief op te halen met deze invoer:
- Opzoekwaarde is "inc" (G4)
- De opzoektabel is 'tarieven' (B5: D11)
- Kolomnummer is 3, cumulatieve belasting
- Overeenkomsttype is 1 = overeenkomst bij benadering
VLOOKUP(inc,rates,3,1) // returns 4,543
Met een belastbaar inkomen van $ 50.000, komt VERT.ZOEKEN, in geschatte overeenkomstmodus, overeen met 39.475, en retourneert 4.543, de totale belasting tot $ 39.475.
De tweede VERT.ZOEKEN berekent het resterende te belasten inkomen:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
als volgt berekend:
(50.000-39.475) = 10.525
Ten slotte krijgt de derde VERT.ZOEKEN het (bovenste) marginale belastingtarief:
VLOOKUP(inc,rates,2,1) // returns 22%
Dit wordt vermenigvuldigd met het inkomen dat in de vorige stap is berekend. De volledige formule is als volgt opgelost:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Marginale en effectieve tarieven
Cel G6 bevat het hoogste marginale tarief, berekend met VERT.ZOEKEN:
=VLOOKUP(inc,rates,2,1) // returns 22%
Het effectieve belastingtarief in G7 is de totale belasting gedeeld door het belastbaar inkomen:
=G5/inc // returns 13.7%
Opmerking: ik kwam deze formule tegen op de blog van Jeff Lenning bij Excel University. Het is een goed voorbeeld van hoe VERT.ZOEKEN kan worden gebruikt in de geschatte overeenkomstmodus, en ook hoe VERT.ZOEKEN meerdere keren in dezelfde formule kan worden gebruikt.
